Hallöle,
ich stelle Euch hier mal ein Backupscript zur Verfügung, welches unter MS Server 2008 bzw. Windows 7/8 lauffähig sein sollte!
Mit einigen Anpassungen sollte es sich leicht an Eure Umgebung anpassen lassen.
Ziel dieses Scriptes ist/war es, eine Sicherung eines bzw. mehrerer Server auf einer zentralen Netzfreigabe abzulegen.
Die Vorgabe war, erst eine (oder mehrere) vollständige Sicherung(en) lokal abzulegen und diese so entstandene Sicherungsdatei anschließend auf eine Netzfreigabe zu kopieren.
Ihr könnt dieses Script gerne benutzen, jedoch gebe ich keine Garantie, dass es in Eurer Umgebung fehlerfrei funktioniert!
Und beschwert Euch nicht bei mir, wenn es nicht funktioniert! Erst testen bevor Ihr es einsetzt!
Feedback erwünscht
Grüße
Jody
@echo off
REM
REM #########################################################################
REM
REM Backup-Script für Windows 2008 Server / Windows7
REM
REM #########################################################################
REM
REM VORBEREITUNG
REM Ab hier werden die Übergabeparameter definiert
REM
REM
REM Hier wird die Parameterübergabe auf Gültigkeit geprüft
REM Parameter 1 = remote Host
If "%1"=="" GOTO SYNTAX
SET HOST=%1
REM Parameter 2 = remote Share
If "%2"=="" GOTO SYNTAX
SET Share=%2
REM Parameter 3 = Anzahl remote Sicherungsdateien
If "%3"=="" GOTO SYNTAX
SET RANZ=%3
REM #########################################################################
REM Hier wird das aktuelle Datum ermittelt und
REM als %BACKUPDATE% in die Reihenfolge JJJJMMTT gebracht:
SET DATUM=%Date%
SET TAG=%Datum:~0,2%
SET MON=%Datum:~3,2%
SET JAHR=%Datum:~6,4%
SET h=%time:~0,2%
SET m=%time:~3,2%
SET BACKUPDATE=%JAHR%%MON%%TAG%
REM hier wird geprüft ob die entfernte Freigabe erreichbar bzw. vorhanden ist, falls nicht wird eine Fehlermeldung ausgegeben
IF NOT EXIST \\%HOST%\%SHARE% GOTO FEHLER
REM Hier wird geprüft, ob ein Unterordner für den Host und Sicherungstyp existiert und ggf. erzeugt
IF NOT EXIST "\\%HOST%\%SHARE%\%BACKUPDATE%" md \\%HOST%\%SHARE%\%BACKUPDATE%
REM #########################################################################
REM #########################################################################
REM Hier erfolgt die eigentliche Sicherung
C:\WINDOWS\system32\wbadmin start backup -backuptarget:\\%HOST%\%SHARE%\%BACKUPDATE% -include c:,d: -allCritical -Systemstate
REM #########################################################################
REM #########################################################################
REM AUFRÄUMEN:
:CLEANUP
REM Damit das Backupverzeichnis nicht voll läuft, wird vor Ende des Scripts
REM geprüft, dass nicht mehr als ANZAHL alter Backup-Dateien vorhanden sind.
for /f "skip=%RANZ% delims=" %%i in ('dir /b /a-d /o-d "\\%HOST%\%SHARE%\%BACKUPDATE%"') do del "\\%HOST%\%SHARE%\%BACKUPDATE%\%%i"
REM
GOTO ENDE
:FEHLER
ECHO Es ist ein Fehler aufgetreten!
ECHO der remote Host ist nicht verfügbar:
ECHO Bitte Netzwerkverbindung oder DNS prüfen!
GOTO ENDE
:SYNTAX
ECHO Die Syntax dieses Befehls lautet:
ECHO.
ECHO Backup.cmd [remote IP] [remote Share] [Anzahl remote Sicherungen]
ECHO [remote IP] = IP des Datensicherungshosts oder OFF
ECHO [remote Share] = Freigabeordner auf Datensicherungshost
ECHO [Anzahl remote Sicherungen] = Anzahl der Sicherungsdateien auf dem DaSiHost
ECHO.
ECHO BEISPIEL: backup.cmd 192.168.1.5 Backup$ 10
pause
GOTO ENDE
:ENDE
Alles anzeigen